Revista CD Expert 8/Revista CD Expert nº 08 CD1.iso/Utilitarios/Office/Where Is It/SETUP.EXE/%MAINDIR%/DescAPI/Sample/SampleModule.dpr

Text File | 1999-04-11 | 5.1 KB | 141 lines

//============================================================================
//                               SampleModule.DLL
//                 WhereIsIt Description API Demontration Module
//                         Robert Galle, November 1998
//============================================================================

library SampleModule;

uses Windows;

{$INCLUDE DescAPI.inc}


//****************************************************************************
//                 Implementation of "Text file import" plugin
//****************************************************************************

procedure ImportTextFile(const FileList, DescResult: PChar; RequireFileProc: TRequireFileProc);

// Plugin will import the first 5 lines of text from first specified description
// file and use it as a description for parent item (folder or archive file).

// NOTE: This is a VERY simplified plugin. It does nothing special, and does
// not include any special data checking or error recovery apart from the
// most basic one. It should only be used as reference to Description API
// implementation, not as a base for any "real" plugins.

const NumLines = 5;   // number of lines to import

var StoreFileMode, n: Integer;
    TextFile: Text;
    TextFilePath: PChar;
    Line,Desc: string;
begin
  // FileList points here to a list of found files, not in any particular order.
  // This list is actually a single stream of null-terminated strings, attached
  // to each other, and an empty string ending the list, for example:
  //  'README.TXT'#0'DESC.TXT'#0'DESC.NFO'#0'LICENSE.TXT'#0#0
  // Each plugin should decide what to do with found files, and which one to
  // use for importing. This sample plugin will just import the first file in
  // the list.

  // Let's request the first file in the list from WhereIsIt
  TextFilePath:=RequireFileProc(FileList);

  // plugin will open file as read-only, so opening should not fail even if
  // file is already opened by some other program.
  StoreFileMode:=FileMode;
  FileMode:=0;   // read-only

   // try to open the file
  AssignFile(TextFile,TextFilePath);
  Reset(TextFile);

   // if something went wrong with opening the file, just leave the description
  // alone and exit
  if IOResult<>0 then Exit;

  try
    // read the first <NumLines> and store them in Desc
    n:=0;
    Desc:='';
    while not EOF(TextFile) and (n<NumLines) do begin
      ReadLn(TextFile,Line);
      Desc:=Desc+#13#10+Line;
      Inc(n);
    end;
    // copy the description to where it is expected (DescResult buffer),
    // but make sure not to exceed the maximum description buffer size
    // specified with MaxDescLength constant!
    LStrCpyN(DescResult,PChar(Desc),MaxDescLength-1);
  finally
    // just clean up an return
    Close(TextFile);
    FileMode:=StoreFileMode;
  end;
end;


//****************************************************************************
//                        Description API interface
//****************************************************************************

procedure ModuleInfo(PluginName, Author, Version: PChar); stdcall;
begin
  // just provides some basic information about description module
  LStrCpy(PluginName, 'WhereIsIt Sample Description Module');
  LStrCpy(Author, 'Robert Galle');
  LStrCpy(Version, '1.0');
end;

procedure ConfigureProc(HInstance: THandle; OwnerWnd: THandle; PluginID: Word); stdcall;
begin
  // this one executes when user requests to configure plugin. In this sample
  // it will just show a simple dialog with version information.
  MessageBox(OwnerWnd,
    PChar('Sample Description Module v1.0'+#13#13'Here could be implemented a '+
          'special dialog where users could configure the plugin.'),
    'About SampleModule.DLL',
    MB_IconInformation+MB_OK);
end;

procedure RegisterDescPlugins(RegisterPlugin: TRegisterPlugin); stdcall;
begin
   // register the plugin in WhereIsIt
   RegisterPlugin(0, ptParentItem, 'Text files import', '*.TXT,*.NFO,READ.ME', ConfigureProc);
end;

function ImportDesc_ParentItem(PluginID: Word; ParentName,FoundList,Desc: PChar;
   RequireFileProc: TRequireFileProc): Boolean; stdcall;
begin
  // This procedure is called for each ptParentItem plugin in this module. It
  // should check requested PluginID, and run the appropriate plugin. Available
  // for plugins are a list of found description files, matching plugin's
  // FileMask (FoundList parameter), and address of buffer where the extracted
  // description is expected.

  // assume that description will be an empty string by default
  Desc[0]:=#0;
 // call appropriate plugin by the PluginID - not much choice, we only have
  // one plugin in this sample
  case PluginID of
    0: if FoundList>'' then ImportTextFile(FoundList,Desc,RequireFileProc);
  end;

  // function should return True if description was retrieved.
  Result:= Desc>'';
end;


// The DLL library needs to export functions required by Description API
exports
  ModuleInfo╨o,
  RegisterDescPlugins,
  ImportDesc_ParentItem;

// That's it. Simple, eh?

begin
end.